Nim

import strutils, times, sequtils, sugar

# check if level transition in record is safe
proc isSafe*(sign:bool, d:int): bool =
  sign == (d>0) and d.abs in 1..3;

#check if record is valid
proc validate*(record:seq[int]): bool =
  let sign = record[0] > record[1];
  return (0..record.len-2).allIt(isSafe(sign, record[it] - record[it+1]))

# check if record is valid as-is
# or if removing any item makes the record valid
proc validate2*(record:seq[int]): bool =
  return record.validate or (0..<record.len).anyIt(record.dup(delete(it)).validate)

proc solve*(input:string): array[2,int] =
  let lines = input.readFile.strip.splitLines;
  let records = lines.mapIt(it.splitWhitespace.map(parseInt));
  result[0] = records.countIt(it.validate);
  result[1] = records.countIt(it.validate2);

I got stuck on part 2 trying to check everything inside a single loop, which kept getting more ugly. So then I switched to just deleting one item at a time and re-checking the record.

Reworked it after first finding the solution to compress the code a bit, though the range iterators don't really help with readability.

I did learn about the sugar import, which I used to make the sequence duplication more compact: record.dup(delete(it).